キャラクターエディタ
シンプルなキャラクターエディタを作成してみました。
実行すると CHR$(255) のキャラクターを表示します。
初期状態ではイチゴです。（255＝#FF）
点滅している部分が現在のカーソルです。
カーソルキーで移動し、スペースキーで状態を変更します。
Enter で POKE に使用できるデータを出力して終了します。
キャラクターの設定は 224（#E0）〜255（#FF）なので、
例えば CHR$(224) に設定したい場合は
POKE 224*8,14,31,31,31,14,8,16,224
とします。短くするために 10 進数出力にしてあります。
また CHR$(255) に反映されているため、
そのまま使用する事ができますし、
誤っている場合は再度 RUN すれば編集しなおせます。
CLP で初期状態のイチゴへ戻す事が可能です。
IchigoJam BASIC 1.2 より採用されている COPY を使う事で、他のキャラクターを簡単に反映できます。
COPY 255*8,235*8,8:RUN ← CHR$(235) のキャラクターを得て表示します。（0〜254 で有効）
COPY 240*8,255*8,8 ← CHR$(240) へキャラクターを反映します。（224〜254 で有効）
10 'ｷｬﾗｸﾀｰｴﾃﾞｨﾀ
20 CLS
30 FOR Y=0 TO 7
40 V=PEEK(255*8+Y)
50 FOR X=7 TO 0 STEP -1
60 IF V&(1<<X) ?CHR$(1); ELSE ?"ﾛ";
70 NEXT:?:NEXT:Y=0
80 LC 9,0:?CHR$(255)
90 LC X,Y:IF VPEEK()<>2 D=VPEEK()
100 A=X:B=Y:I=INKEY()
110 X=(X-(I=28)+(I=29)+8)%8
120 Y=(Y-(I=30)+(I=31)+8)%8
130 IF A<>X OR B<>Y ?CHR$(D);:GOTO 90
140 IF I=32 GOTO 180
150 IF I=10 GOTO 210
160 IF TICK()%60/30 ?CHR$(2); ELSE ?CHR$(D);
170 GOTO 90
180 IF D=1 ?"ﾛ"; ELSE ?CHR$(1);
190 D=PEEK(255*8+Y)^(1<<(7-X))
200 POKE 255*8+Y,D:GOTO 90
210 LC 0,9
220 FOR Y=0 TO 7
230 D=PEEK(255*8+Y)
240 ?D;:IF Y<>7 ?",";
250 NEXT:?:?
IchigoJam web でプログラムを実行します。
このQRコードはアクセス解析のためにCookieを使用しています。
アクセス解析は匿名で収集されており、個人を特定するものではありません。
この機能はCookieを無効にすることで収集を拒否することができますので、
お使いのデバイスのブラウザの設定をご確認ください。
MixJuice ダウンロード ?"MJ GET kidspod.club/mj/602
MicJack ダウンロード ?"MJ GKP 602
他の方が作ったエディタ
他にも IchigoJam BASIC プログラムやパソコン・スマートフォン向けのアプリとしていくつか公開されています。
-
8x16ドットキャラクターエディタ for IchigoJam | 福野泰介の一日一創
福野さん作。#E0・#E1 を縦につなげた 2 文字分 8×16 ドットで制作できます。 -
えもじをつくろう | 十勇士パソコンクラブ
8x8 の 1 文字分によるエディタ。編集後は 2 進数で POKLE を表示します。 -
PCGエディタ | Facebook グループ
IchigoJam-FAN 内
前野 秀史 さん作。16✕16 の 4 文字分によるエディタ。リアルタイムに 16 進数を表示します。 -
ichigojam その１８ Tinyキャラクタエディタ
| 電子工作その他色々
ichigojam用Ｔｉｎｙキャラクタエディタ | YouTube
見習職人さん（＝tk2016 さん）作。#E0～#E7 を文字単位（8×8）で制作できます。 -
POKEでキャラクター制作
伊藤 貴史さん作。Web ブラウザ上で 1 文字分（8×8）制作できます。
パソコン・スマートフォン・タブレット端末の最新ブラウザで動作可能のようです。
また、Micono Utilities で公開されている
シリアル転送やファームウェア更新が行えるアプリ IJUtilities に
エディタが含まれています。（右画像）
macOS・Windows・Linux・Raspberry Pi 阪が存在します。
起動後、ターミナルセンターの
ツールバー オプション - PCG Editor で起動できます。
複数文字を連結した状態で制作でき、
また出力結果として 2・8・10・16 進数に対応しています。
イチゴジャム レシピ では jig.jp・B Inc.・na-s.jp (株式会社ナチュラルスタイル)
の確認・了承を得て商標・公式ロゴを使用しています。
IchigoLatte is a registered trademark in Japan
of the Natural Style Co,Ltd. (na-s.jp)
IchigoJam Recipe (イチゴジャム レシピ) has confirmation and approval
for the use of trademarks and official logos of jig.jp, B Inc. and na-s.jp.
SkyBerryJAM は 栃木県立栃木工業高等学校 が管理する登録商標であり、
SkyBerryJAM は 栃木県立栃木工業高等学校 の商標です。
managed by Tochigi Technical High School (Tochiko)
Raspberry Pi は
Raspberry Pi 財団 の登録商標です。
Raspberry Pi is a registered trademark or
trademark of
the Raspberry Pi Foundation.
"RISC-V" の商品名は RISC-Vインターナショナル が管理する登録商標です。
The “RISC-V” trade name is a registered trade mark of
RISC-V International.
イチゴジャム レシピ は jig.jp・B Inc.・na-s.jp・
IchigoJam Recipe (イチゴジャム レシピ) is NOT an official website
by jig.jp, B Inc., na-s.jp and PCN (Program Club Network).
クリエイティブ・コモンズ 表示 4.0 国際 ライセンス
(シェアボタン、PanCake 公式ロゴ、MSX フォント、
(Share button, PanCake Offical Logo, MSX font, Nyan Cat,
Denshi Kousaku Magazine & Micom BASIC Magazine Images,
Petit Computer Images, KDDI / Jimdo footer and
objects with the license specification are excluded)