キャラクターコード一覧 16進数・10進数

BASIC/はじめの一歩 の キャラクターコード で表示している

16 進数・10 進数別のキャラクターコード表示で

実際に使用しているプログラムです。

当初は手作業で行っていたのですが、後のコード変更を考えて

プログラム化してありました。

せっかくなのでプログラム公開しておきます。

 

実行すると右のように一覧表示します。

画面キャプチャの考慮で、OK 表示はわざと下に出しています。

 

全キャラクターを表示させるために POKE を用いているので

IchigoJam BASIC 1.0.0 (0.9.8 RC2) 以降となっています。

モニタは POKE でシリアルへ送出しないため、非対応です。

ここのキャプチャ画像は IchigoJam BASIC 1.2・カナ版で、

バージョンによって表示が異なります。

IchigoJam web や IchigoJam BASIC RPi は動作可能です。


BASIC 1.0.0~ (0.9.8-RC2~)・16進数

10 'キャラクターコード イチラン 16
20 CLS
30 FOR C=0 TO 255
40 X=C%16:Y=C/16
50 POKE #900+(Y+2)*32+X+2,C
60 NEXT
70 FOR C=0 TO 15
80 LC C+2,0:?HEX$(C)
90 LC C+2,1:?CHR$(145)
100 LC 0,C+2:?HEX$(C);CHR$(146)
110 NEXT
120 LC 1,1:?CHR$(152)
130 LC 0,0:?"\"
140 LC 0,18
150 END

IchigoJam web でプログラムを実行します。

このQRコードはアクセス解析のためにCookieを使用しています。

アクセス解析は匿名で収集されており、個人を特定するものではありません。

この機能はCookieを無効にすることで収集を拒否することができますので、
お使いのデバイスのブラウザの設定をご確認ください。

MixJuice ダウンロード ?"MJ GET kidspod.club/mj/651

MicJack ダウンロード ?"MJ GKP 651



BASIC 1.0.0~ (0.9.8-RC2~)・10進数

10 'キャラクターコード イチラン 10
20 CLS
30 FOR C=0 TO 255
40 X=C%20:Y=C/20
50 POKE #900+(Y+3)*32+X+4,C
60 NEXT
70 FOR C=0 TO 19
80 LC C+4,0:IF C>9 ?C/10
90 LC C+4,1:?C%10
100 LC C+4,2:?CHR$(145)
110 NEXT
120 FOR C=0 TO 255/20
125 'LC 0,X+3
126 '? DEC$(C*20,3);CHR$(146)
130 LC 0,C+3:IF C=0 ?" ";
140 IF C*20<100 ?" ";
150 ?C*20;CHR$(146)
160 NEXT
170 LC 3,2:?CHR$(152)
180 LC 2,1:?"\"
190 LC 1,0:?"\"
200 LC 0,16
210 END

130~150 の代わりに 125~126 でも同じ表示になります。

DEC$ は IchigoJam BASIC 1.1.0 から使えるコマンドです。


IchigoJam web でプログラムを実行します。

このQRコードはアクセス解析のためにCookieを使用しています。

アクセス解析は匿名で収集されており、個人を特定するものではありません。

この機能はCookieを無効にすることで収集を拒否することができますので、
お使いのデバイスのブラウザの設定をご確認ください。

MixJuice ダウンロード ?"MJ GET kidspod.club/mj/652

MicJack ダウンロード ?"MJ GKP 652



BASIC 0.7.4~1.1.1 (1.2 beta 14)・10 進数

10 'Character Code 20 OLD
20 CLS
30 C=0
40 LOCATE C%20+6,C/20+5
50 PRINT CHR$(C);
60 C=C+1
70 IF C<256 GOTO 40
80 X=0
90 IF X<10 GOTO 120
100 LOCATE X+6,2
110 PRINT X/10
120 LOCATE X+6,3
130 PRINT X%10
140 LOCATE X+6,4
150 PRINT CHR$(23);
160 X=X+1
170 IF X<20 GOTO 90
180 Y=0
190 LOCATE 2,Y/20+5
200 IF Y=0 PRINT " ";
210 IF Y<100 PRINT " ";
220 PRINT Y;CHR$(22); 
230 Y=Y+20
240 IF Y<256 GOTO 190
250 LOCATE 5,4
260 PRINT CHR$(24);
270 LOCATE 0,22

MixJuice ダウンロード ?"MJ GET kidspod.club/mj/845

MicJack ダウンロード ?"MJ GKP 845


 

横幅 20 文字・10 進数仕様で古いバージョンで表示できるようにしたバージョンです。

 

CHR$() が 0.7.4 対応なので、それ以降となります。

LOCATE・PRINT を使用しているので、0.9.8-RC 以降は一部のキャラクターを表示できません。
現在のバージョンでも崩れずに表示できるのですが、1.2.0 からキャラクターの変更で罫線に問題が出ます。

(そのため、比較的最新版をベースにしている IchigoJam web のボタンは外しています)

 

DEC・POKE・#(16 進数)・FOR~NEXT・LC・? など初期は使えないコマンドがいろいろありました。


他のバージョン