拡大文字
PEEK で容易にキャラクターの取り出しが
できるようになったので、それを応用して
大きな文字を表示するプログラムを作ってみました。
実行すると3度 ? を表示します。
横4文字×縦3文字の12文字をここで入力して下さい。
すると右下から順々に入力した文字が大きく表示されます。
表示が行われた後はキー入力待ちとなります。
わざわざ 140 を POKE で線画しているのは、
一番下の座標 23 を PRINT で線画すると
スクロールしてしまうため、POKE を使用しています。
そのため、130 で出力場所を計算しています。
改良を行う場合、IchigoJam の FOR〜NEXT は
4重までになっていて、これを使いきっているため
これ以上ループを増やせない事にご注意下さい。
また、このプログラムでは
#900〜#BFF を POKE で書き込んでいますが、
#C00 以降はプログラム領域となっているため、
最悪プログラムを破損させます。
実行前の SAVE を忘れないで下さい。
10 'ｶｸﾀﾞｲﾓｼﾞ
20 CLV
30 CLS
40 FOR Y=0 TO 2
50 INPUT I
60 NEXT
70 FOR Y=2 TO 0 STEP -1
80 FOR X=3 TO 0 STEP -1
90 LET I,VPEEK(X+1,Y)
100 FOR V=0 TO 7
110 LET P,PEEK(I*8+V)
120 FOR W=0 TO 7
130 LET Q,(Y*8+V)*32+(X*8+W)
140 POKE #900+Q,(P&128<>0)
150 LET P,P<<1
160 NEXT
170 NEXT
180 NEXT
190 NEXT
200 IF INKEY() GOTO 200
210 IF !INKEY() GOTO 210
IchigoJam web でプログラムを実行します。
このQRコードはアクセス解析のためにCookieを使用しています。
アクセス解析は匿名で収集されており、個人を特定するものではありません。
この機能はCookieを無効にすることで収集を拒否することができますので、
お使いのデバイスのブラウザの設定をご確認ください。
MixJuice ダウンロード ?"MJ GET kidspod.club/mj/597
MicJack ダウンロード ?"MJ GKP 597
配列版
入力の代わりに予め配列 [0]〜[11] に入れておき、実行ですぐに表示を行うようにしたバージョンです。
左上が [0] 右へ4文字ずつ下に向かって表示し [11] が右下となります。
直接配列にコードを入れます。ASC で表示する文字を入れる事も可能です。
10 'ｶｸﾀﾞｲﾓｼﾞ ﾊｲﾚﾂﾊﾞﾝ
20 CLV
30 CLS
40 LET [0],ASC("I"),ASC("c")
50 LET [2],ASC("h"),ASC("i")
60 LET [4],0 ,ASC("g")
70 LET [6],ASC("o"),0
80 LET [8],ASC("J"),ASC("a")
90 LET [10],ASC("m"),255
100 FOR O=0 TO 11
110 LET X,O%4
120 LET Y,O/4
130 LET I,[O]
140 FOR V=0 TO 7
150 LET P,PEEK(I*8+V)
160 FOR W=0 TO 7
170 LET Q,(Y*8+V)*32+(X*8+W)
180 POKE #900+Q,(P&128<>0)
190 LET P,P<<1
200 NEXT
210 NEXT
220 NEXT
230 IF INKEY() GOTO 230
240 IF !INKEY() GOTO 240
IchigoJam web でプログラムを実行します。
このQRコードはアクセス解析のためにCookieを使用しています。
アクセス解析は匿名で収集されており、個人を特定するものではありません。
この機能はCookieを無効にすることで収集を拒否することができますので、
お使いのデバイスのブラウザの設定をご確認ください。
MixJuice ダウンロード ?"MJ GET kidspod.club/mj/598
MicJack ダウンロード ?"MJ GKP 598
文字列版
1.2 より対応した文字列を使用したバージョンです。
40 にある D の文字列は必ず 12 文字にして下さい。満たない場合は空白を入れて下さい。
10 'ｶｸﾀﾞｲﾓｼﾞ ﾓｼﾞﾚﾂﾊﾞﾝ
20 CLV
30 CLS
40 LET D,"Ichi go Jam"
50 FOR O=0 TO 11
60 LET X,O%4
70 LET Y,O/4
80 LET I,ASC(D+O)
90 FOR V=0 TO 7
100 LET P,PEEK(I*8+V)
110 FOR W=0 TO 7
120 LET Q,(Y*8+V)*32+(X*8+W)
130 POKE #900+Q,(P&128<>0)
140 LET P,P<<1
150 NEXT
160 NEXT
170 NEXT
180 IF INKEY() GOTO 180
190 IF !INKEY() GOTO 190
IchigoJam web でプログラムを実行します。
このQRコードはアクセス解析のためにCookieを使用しています。
アクセス解析は匿名で収集されており、個人を特定するものではありません。
この機能はCookieを無効にすることで収集を拒否することができますので、
お使いのデバイスのブラウザの設定をご確認ください。
MixJuice ダウンロード ?"MJ GET kidspod.club/mj/599
MicJack ダウンロード ?"MJ GKP 599
PanCake 版
VIDEO コマンドによる拡大
IchigoJam BASIC 1.2.2（1.2 beta 34-5）および IchigoJam BASIC 1.2.5RPi（1.2beta17RPi） より
VIDEO コマンドが拡張され、最新版では簡単に拡大文字を表示できるようになっています。
10 VIDEO 7
20 PRINT"Ichi go Jam";
30 IF !INKEY() CONT
40 VIDEO 1
イチゴジャム レシピ では jig.jp・B Inc.・na-s.jp (株式会社ナチュラルスタイル)
の確認・了承を得て商標・公式ロゴを使用しています。
IchigoLatte is a registered trademark in Japan
of the Natural Style Co,Ltd. (na-s.jp)
IchigoJam Recipe (イチゴジャム レシピ) has confirmation and approval
for the use of trademarks and official logos of jig.jp, B Inc. and na-s.jp.
SkyBerryJAM は 栃木県立栃木工業高等学校 が管理する登録商標であり、
SkyBerryJAM は 栃木県立栃木工業高等学校 の商標です。
managed by Tochigi Technical High School (Tochiko)
Raspberry Pi は
Raspberry Pi 財団 の登録商標です。
Raspberry Pi is a registered trademark or
trademark of
the Raspberry Pi Foundation.
"RISC-V" の商品名は RISC-Vインターナショナル が管理する登録商標です。
The “RISC-V” trade name is a registered trade mark of
RISC-V International.
イチゴジャム レシピ は jig.jp・B Inc.・na-s.jp・
IchigoJam Recipe (イチゴジャム レシピ) is NOT an official website
by jig.jp, B Inc., na-s.jp and PCN (Program Club Network).
クリエイティブ・コモンズ 表示 4.0 国際 ライセンス
(シェアボタン、PanCake 公式ロゴ、MSX フォント、
(Share button, PanCake Offical Logo, MSX font, Nyan Cat,
Denshi Kousaku Magazine & Micom BASIC Magazine Images,
Petit Computer Images, KDDI / Jimdo footer and
objects with the license specification are excluded)