IchigoJam 拡大文字

IchigoJam BASIC での拡大表示は公開してありますが、

IchigoJam で入力した文字を PanCake で表示する方法は

あまり公開されていなかったので、作ってみました。

PanCake の背景に IchigoJam BASIC の文字を表示できます。

 

拡大文字 (IchigoJam BASIC 版)

 

実行すると IchigoJam で入力画面になるので、

横10桁×縦5行の範囲で文字を入力して下さい。

すると PanCake の画面で背景を表示した上に

入力した文字を拡大表示します。

何かキーを押すと IchigoJam 画面へ戻ります。

20 の C=1 で文字色、100 で背景を変更できます。

 

IchigoJam で PEEK を使用し取り出したキャラクターを

PanCake の STAMP1 で出力させています。

スプライトモードではこの方法を使用できないため、

スプライトで用意されている英数を使用すると良いでしょう。

 

PanCakeプチコン3号Edition では

プログラムをそのまま実行すると文字が見難くなります。
100 ?"PANCAKE IMAGE 04 " の 04(背景画像)を変更するか、

20 C=1 の 1(文字色)を変更して下さい。

 


10 'PanCake IchigoJamカクダイモジ
20 CLS:CLV:C=1
30 FOR Y=0 TO 4
40 INPUT K:NEXT
50 FOR Y=0 TO 4
60 FOR X=0 TO 9
70 [Y*10+X]=SCR(X+1,Y)
80 NEXT:NEXT:VIDEO 0
85 IF VER()>11000 UART 1
90 ?"PANCAKE VIDEO 01
100 ?"PANCAKE IMAGE 04
110 FOR Y=0 TO 4
120 FOR X=0 TO 9
130 ?"PANCAKE STAMP1 ";
140 ? HEX$(X*8,2);" ";
150 ? HEX$(Y*8+3,2);" ";
160 ? HEX$(C,2);" ";
170 FOR V=0 TO 7
180 ? HEX$(PEEK([Y*10+X]*8+V),2);
190 NEXT:?:NEXT:NEXT
200 IF !INKEY() GOTO 200
210 ?"PANCAKE VIDEO 00
220 VIDEO 1

MixJuice ダウンロード ?"MJ GET kidspod.club/mj/621

MicJack ダウンロード ?"MJ GKP 621


配列版

予めプログラム上で配列に表示させる文字を入れておき、実行ですぐに表示できるバージョンです。

[0]〜[9] が一番上の行、[30]〜[39] が一番下の行になります。プログラム容量の都合で縦4行にしています。

プログラムでは ASC で実際に表示する文字を入れていますが、ASC を外してキャラクターコードを使用する事も可能です。

10 'PanCake IchigoJamカクダイモジ
20 LET[0],ASC("0"),ASC("1")
30 LET[2],ASC("2"),ASC("3")
40 LET[4],ASC("4"),ASC("5")
50 LET[6],ASC("6"),ASC("7")
60 LET[8],ASC("8"),ASC("9")
70 LET[10],ASC("A"),ASC("B")
80 LET[12],ASC("C"),ASC("D")
90 LET[14],ASC("E"),ASC("F")
100 LET[16],ASC("G"),ASC("H")
110 LET[18],ASC("I"),ASC("J")
120 LET[20],ASC("K"),ASC("L")
130 LET[22],ASC("M"),ASC("N")
140 LET[24],ASC("O"),ASC("P")
150 LET[26],ASC("Q"),ASC("R")
160 LET[28],ASC("S"),ASC("T")
170 LET[30],ASC("U"),ASC("V")
180 LET[32],ASC("W"),ASC("X")
190 LET[34],ASC("Y"),ASC("Z")
200 LET[36],ASC("イ"),ASC("チ")
210 LET[38],ASC("コ"),ASC("゙")
220 VIDEO 0:C=1
225 IF VER()>11000 UART 1
230 ?"PANCAKE VIDEO 01
240 ?"PANCAKE IMAGE 01
250 FOR Y=0 TO 3
260 FOR X=0 TO 9
270 ?"PANCAKE STAMP1 ";
280 ? HEX$(X*8,2);" ";
290 ? HEX$(Y*8+13,2);" ";
300 ? HEX$(C,2);" ";
310 FOR V=0 TO 7:A=Y*10+X
320 ? HEX$(PEEK([A]*8+V),2);
330 NEXT:?:NEXT:NEXT
340 IF !INKEY() GOTO 340
350 ?"PANCAKE VIDEO 00
360 VIDEO 1

MixJuice ダウンロード ?"MJ GET kidspod.club/mj/645

MicJack ダウンロード ?"MJ GKP 645


文字列版

IchigoJam BASIC 1.2 より対応している文字列を用いたバージョンです。

必ず 1 つの文字列は 10 文字にして下さい。 

10 'PanCake IchigoJam String
20 [0]="          "
30 [1]="PanCake   "
40 [2]="    and   "
50 [3]=" IchigoJam"
60 [4]="          "
70 VIDEO 0:C=1:UART 1
80 ?"PANCAKE VIDEO 01
90 ?"PANCAKE IMAGE 04
100 FOR Y=0 TO 4
110 FOR X=0 TO 9
120 ?"PANCAKE STAMP1 ";
130 ? HEX$(X*8,2);" ";
140 ? HEX$(Y*8+3,2);" ";
150 ? HEX$(C,2);" ";
160 A=ASC([Y]+X)
170 FOR V=0 TO 7
180 ? HEX$(PEEK(A*8+V),2);
190 NEXT:?:NEXT:NEXT
200 IF !INKEY() GOTO 200
210 ?"PANCAKE VIDEO 00
220 VIDEO 1

MixJuice ダウンロード ?"MJ GET kidspod.club/mj/646

MicJack ダウンロード ?"MJ GKP 646